// Klavdia, labman's wife, 223.2
//~Change 33 1
~Begin
-32
 ~Text 7 "Leave immediately "
 ~Wait
 ~Halt
;
-33
 ~If_done 31 !
  ~Text 7 "Hi again. "
 /If_done 31 !
 ~If_done 31
  ~Text 7 "Is Onufry all right? "
 /If_done 31
;
~Default
 ~Text 7 "What do you need here? "
 ~Change 33 1
;
/Begin
~All_questions
 30 I need chemistry reference book.
 33 What's your name?
 ~Always 1 Time to go.
/All_questions
-30
 ~If_done 31

  ~Text 7 "I've given you the only one! "
  ~Wait
  ~Start_again

 /If_done 31


 ~Text 7 "Why do you expect me to do it? "
 ~Question
  31 Your husband promised to help me.
  32 Doesn't matter. Simply give it to me.
  33 If you don't want to help me, I'll have to go.
 /Question
 ~Answer
  31
   ~Text 7 "Onufry!? What's with him, when will I see him? "
   ~Question
    34 Unfortunately, I don't know that.
    35 As soon as you give me the book!.
    36 Never!
   /Question
   ~Answer
    34
     ~Text3 7 "What? You get in here, claim for the book and don't want to"
               speak!
     /.
     ~Text3 15 "But I really don't know anything! I could only get into "
                laboratory and deal with your husband.
     /.

     ~Text3 7 "Oh, excuse me, but I'm so much worried. They don't let him out"
               of laboratory for 2 days. Did you see him, how is it going?.
     /.
     ~Question
      37 He's in norm: alive and healthy.
      38 Stop questioning me. I want the book.
     /Question
     ~Answer
      37
       ~Text 7 "Well you've calmed me a bit... Oh yes, and here's the book. "
       ~Change 31 1
// ~Change 30 0

       ~Take 12 1
      /.
      38
       ~Text 7 "Noway! Tell me about him at first!"
       ~Text 15 "He's okay. But hurry, please!"

       ~Text 7 "I see. Here, keep it. "
       ~Change 31 1
// ~Change 30 0
       ~Take 12 1

      /.
     /Answer
     // 37
    /.
    35
     ~Text 7 "Please, take whatever you want, but let him go! "
     ~Text 15 "I only need the reference book. "

     ~Text 7 "Then keep it! "
     ~Change 31 1
// ~Change 30 0
     ~Take 12 1
    /.
    36
     ~Text 7 "I do not want to see you! "
     ~Change 32 1
     ~Wait
     ~Halt
    /.
   /Answer
   // 34
  /.
  32
   ~Text 7 "You, gangster! Get out of here! "
   ~Change 32 1
   ~Wait
   ~Halt
  /.
  33
   ~Text 7 "Good-bye".
   ~Wait
   ~Halt
  /.
 /Answer
 // 31
;
-33
 ~Text 7 "Klavdia."
 ~Question
  34 How are you?
  35 I see.
 /Question
 ~Answer
  34
   ~If_done 31 !
    ~Text3 7 "To tell the truth - bad. Sorry, but I don't like speaking at"
              the moment.
    /.
   /If_done 31 !

   ~If_done 31
    ~Text 7 "And how do you think? "
   /If_done 31
  /.
  35
   ~Text 7 "You'd better leave now. "
  /.
 /Answer
;
-Always 1

  ~If_done 31
   ~Text 7 "Come with news about the husband. "
  /If_done 31
  ~If_done 31 !
   ~Text 7 "Good-bye."
  /If_done 31 !
  ~Wait
  ~Halt
;
~Eof